Project:SPARQL/examples: Difference between revisions

Project:SPARQL/examples (view source)

Revision as of 09:08, 10 March 2024

5,090 bytes added , 2 months ago

→‎Residences of women participants in Colchester excavations

Sharon

579

edits

@@ Line 1,966: / Line 1,966: @@
 }
 ORDER BY ?locationLabel
+</sparql>
+=== IWD 2024 Map of five women's places ===
+<sparql tryit="1">
+## how many places for the five women can I get on a map? a slightly ridiculous query.
+#title:Four stories, five women, many places for #IWD2024
+PREFIX bnwd: <https://beyond-notability.wikibase.cloud/entity/>
+PREFIX bnwds: <https://beyond-notability.wikibase.cloud/entity/statement/>
+PREFIX bnwdv: <https://beyond-notability.wikibase.cloud/value/>
+PREFIX bnwdt: <https://beyond-notability.wikibase.cloud/prop/direct/>
+PREFIX bnp: <https://beyond-notability.wikibase.cloud/prop/>
+PREFIX bnps: <https://beyond-notability.wikibase.cloud/prop/statement/>
+PREFIX bnpq: <https://beyond-notability.wikibase.cloud/prop/qualifier/>
+#defaultView:Map{"hide":["?geo"],"layer":"?person", "markercluster":true }
+SELECT distinct ?person ?personLabel  ?propLabel ?placeLabel  ?geo  ?loc2Label (year(?date) as ?year)
+WHERE {
+   VALUES (?person) {(bnwd:Q894) (bnwd:Q462) (bnwd:Q549) (bnwd:Q921) (bnwd:Q1053) }  #
+   ?person ( bnp:P29 | bnp:P94  | bnp:P23 | bnp:P13 | bnp:P120   ) ?s .
+   ?s  ( bnps:P29 | bnps:P94  | bnps:P23 | bnps:P13 | bnps:P120   )  ?place .
+   ?person ?p ?s .
+      ?prop wikibase:claim ?p;
+         wikibase:statementProperty ?ps.
+      optional { ?s ( bnpq:P1 | bnpq:P27 ) ?date . }
+      #optional { ?s bnpq:P31 ?street . }
+  # LOLplaces
+  #1 geocoords in quals for place itself - should be detailed geo added manually, cf London district geocoords which =main P153
+  #2 wikdiata geocoords for place
+  #3 geocoords in quals for linked place
+  #4 wikidata geocoords for linked place
+  #5 wikidata geocoords in place P2 qual
+  #6 `of` qual geocoords
+  #7 `of` P2 wikidata geocoords
+  #8 `of` wikidata geocoords
+  #9 place main geocoords - likely to be broad london postal districts so should be last resort
+      optional { ?s bnpq:P153 ?geo1 . } # place has geocoords directly *in qualifier*
+      optional { ?place bnwdt:P2 ?linked_p1 . # linked place has geocoords *in qualifier* (this is primarily for SAL?)
+                     ?linked_p1 bnp:P2 ?llp_s .
+                        ?llp_s bnps:P2 ?llp_p1.
+                        ?llp_s bnpq:P153 ?geo2 .
+                }
+      optional { ?place bnwdt:P117 ?pws .  # place has wikidata page that has geoocords (main P625, not anywhere else)
+                   bind(iri(concat("http://www.wikidata.org/entity/", str(?pws))) as ?pwikidata) .
+                   SERVICE <https://query.wikidata.org/sparql> {
+                     ?pwikidata wdt:P625 ?geo3 .
+                  }
+                }
+      optional { ?place bnwdt:P2 ?linked_p2 .  # linked place has wikidata geocoords
+                    ?linked_p2 bnwdt:P117 ?lws .  # wikidata id P117
+                     bind(iri(concat("http://www.wikidata.org/entity/", str(?lws))) as ?lwikidata) .
+                     SERVICE <https://query.wikidata.org/sparql> {
+                      ?lwikidata wdt:P625 ?geo4 .
+                     }
+                }
+      optional { ?s bnpq:P2 ?qp1 . # P2 qualifier location has wikidata geocoords
+                     ?qp1 bnwdt:P117 ?qws .
+                     bind(iri(concat("http://www.wikidata.org/entity/", str(?qws))) as ?qwikidata) .
+                     SERVICE <https://query.wikidata.org/sparql> {
+                      ?qwikidata wdt:P625 ?geo5 .
+                     }
+                 }
+      optional { ?s bnpq:P78 ?ofp1 . # 'of' (organisation) has geocoords in P2 qualifier
+                    ?ofp1 bnp:P2 ?ofp1_s .
+                     ?ofp1_s bnps:P2 ?ofp1_p .
+                     ?ofp1_s bnpq:P153 ?geo6 . }
+      optional { ?s bnpq:P78 ?ofp2 . # 'of' (organisation) P2 location has wikidata geocoords
+                    ?ofp2 bnwdt:P2 ?ofp2_p .
+                       ?ofp2_p bnwdt:P117 ?ofl2ws .
+                       bind(iri(concat("http://www.wikidata.org/entity/", str(?ofl2ws))) as ?ofl2wikidata) .
+                       SERVICE <https://query.wikidata.org/sparql> {
+                      ?ofl2wikidata wdt:P625 ?geo7 .  }
+              }
+      optional { ?s bnpq:P78 ?ofp3 .   # 'of' (organisation) has wikidata geocoords
+                    ?ofp3 bnwdt:P117 ?ofpws .  # wikidata id P117
+                     bind(iri(concat("http://www.wikidata.org/entity/", str(?ofpws))) as ?ofpwikidata) .
+                     SERVICE <https://query.wikidata.org/sparql> {
+                      ?ofpwikidata wdt:P625 ?geo8 .  }
+                }
+      optional { ?place bnwdt:P153 ?geo9 .  } # geocoords in BN as main (mainly london postal districts - should be last resort as v broad.)
+  BIND(COALESCE(?geo1, ?geo2, ?geo3, ?geo4, ?geo5, ?geo6, ?geo7, ?geo8, ?geo9) AS ?geo).  # if geo1 available use that, then try geo2, and so on
+  bind(coalesce(?linked_p1, ?linked_p2, ?qp1, ?ofp1, ?ofp2, ?ofp3 ) as ?loc2). # hopefully get extra context where place is just sthg like "meeting". though exactly what will be variable!
+  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en-gb". }
+}
+order by ?personLabel ?date ?placeLabel
 </sparql>